@echo off
setlocal EnableDelayedExpansion
title Install all tools (administrator)

rem Runs every ??-Install-*-Admin.bat next to this file in numeric order.
rem Run 00-Install-All-User.bat afterwards, as the user who will use the tools.

fltmc >nul 2>&1
if errorlevel 1 (
    echo Please right-click this file and choose "Run as administrator".
    pause
    exit /b 1
)

rem The child scripts skip their final pause when this is set.
set "INSTALL_ALL=1"
set "FAILED="
set "REBOOT="

for %%F in ("%~dp0??-Install-*-Admin.bat") do (
    if /i not "%%~nxF"=="%~nx0" (
        echo.
        echo ===== %%~nxF =====
        call "%%F"
        set "RC=!ERRORLEVEL!"
        if "!RC!"=="3010" set "REBOOT=1"
        if not "!RC!"=="0" if not "!RC!"=="3010" set "FAILED=!FAILED! %%~nxF"
    )
)

echo.
if defined FAILED (
    echo Failed:%FAILED%
) else (
    echo All administrator installers finished.
)
if defined REBOOT echo A reboot is required to finish some installations.
pause
if defined FAILED exit /b 1
exit /b 0